library(sgml), a foreign library for SWI-Prolog to parse
SGML and XML documents, returning information on both the document and
the document's DTD. The parser is designed to be small, fast and
flexible.
Markup languages have recently regained popularity for two reasons. One is document exchange, which is largely based on HTML, an instance of SGML, and the other is for data exchange between programs, which is often based on XML, which can be considered a simplified and rationalised version of SGML.
James Clark's SP parser is a flexible SGML and XML parser. Unfortunately it has some drawbacks. It is very big, not very fast, cannot work under event-driven input and is generally hard to program beyond the scope of the well designed generic interface. The generic interface however does not provide access to the DTD, does not allow for flexible handling of input or parsing the DTD independently of a document instance.
The parser described in this document is small (less than 100 kBytes executable on a Pentium), fast (between 2 and 5 times faster than SP), provides access to the DTD, and provides flexible input handling.
The document output is equal to the output produced by xml2pl, an SP interface to SWI-Prolog written by Anjo Anjewierden.
This package allows you to parse SGML, XML and HTML data into a
Prolog data structure. The high-level interface defined in library(sgml)
provides access at the file-level, while the low-level interface defined
in the foreign module works with Prolog streams. Please use the source
of sgml.pl as a starting point for dealing with data from
other sources than files, such as SWI-Prolog resources, network-sockets,
character strings, etc. The first example below loads an HTML
file.
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 3.2//EN"> <html> <head> <title>Demo</title> </head> <body> <h1 align=center>This is a demo</title> Paragraphs in HTML need not be closed. This is called `omitted-tag' handling. </body> </html>
?- load_html('test.html', Term, []),
pretty_print(Term).
[ element(html,
[],
[ element(head,
[],
[ element(title,
[],
[ 'Demo'
])
]),
element(body,
[],
[ '\n',
element(h1,
[ align = center
],
[ 'This is a demo'
]),
'\n\n',
element(p,
[],
[ 'Paragraphs in HTML need not be closed.\n'
]),
element(p,
[],
[ 'This is called `omitted-tag\' handling.'
])
])
])
].
The document is represented as a list, each element being an atom to
represent CDATA or a term element(Name, Attributes,
Content). Entities (e.g. <) are expanded and
included in the atom representing the element content or attribute
value.1Up to SWI-Prolog 5.4.x,
Prolog could not represent wide characters and entities that
did not fit in the Prolog characters set were emitted as a term number(+Code).
With the introduction of wide characters in the 5.5 branch this is no
longer needed.
These predicates are for basic use of the library, converting entire and self-contained files in SGML, HTML, or XML into a structured term. They are based on load_structure/3.
dialect(sgml)dialect(xml)dialect(HTMLDialect),
where HTMLDialect is html4 or html5
(default), depending on the Prolog flag html_dialect. Both
imply the option shorttag(false). The option dtd(DTD)
is passed, where DTD is the HTML DTD as obtained using dtd(html,
DTD). See dtd/2.
SGML or XML files are loaded through the common predicate load_structure/3. This is a predicate with many options. For simplicity a number of commonly used shorthands are provided: load_sgml_file/2, load_xml_file/2, and load_html_file/2.
stream(StreamHandle) or a file-name. Options is
a list of options controlling the conversion process.
A proper XML document contains only a single toplevel element whose name matches the document type. Nevertheless, a list is returned for consistency with the representation of element content. The ListOfContent consists of the following types:
CDATA. Note this is possible in
SWI-Prolog, as there is no length-limit on atoms and atom garbage
collection is provided.ListOfAttributes is a list of Name=Value
pairs for attributes. Attributes of type CDATA are returned
literal. Multi-valued attributes (NAMES, etc.) are
returned as a list of atoms. Handling attributes of the types NUMBER
and NUMBERS depends on the setting of the number(+NumberMode)
attribute through
set_sgml_parser/2
or load_structure/3.
By default they are returned as atoms, but automatic conversion to
Prolog integers is supported. ListOfContent defines the
content for the element.
SDATA is
encountered, this term is returned holding the data in Text.NDATA is
encountered, this term is returned holding the data in Text.
<?...?>), Text
holds the text of the processing instruction. Please note that the
<?xml ...?> instruction is handled internally.
The Options list controls the conversion process. Currently defined options are:
<!DOCTYPE ...>
declaration is ignored and the document is parsed and validated against
the provided DTD. If provided as a variable, the created DTD is
returned. See section 3.5.sgml (default),
html4, html5, html (same as html4,
xhtml, xhtml5, xml and xmlns.
See the option dialect of set_sgml_parser/2
for details.//> still closes the
element-tag in XML mode. It may be set to false for parsing HTML
documents to allow for unquoted URLs containing /xml:space. See
section 3.2.NUMBER and NUMBERS
are handled. If token (default) they are passed as an atom.
If
integer the parser attempts to convert the value to an
integer. If successful, the attribute is passed as a Prolog integer.
Otherwise it is still passed as an atom. Note that SGML defines a
numeric attribute to be a sequence of digits. The -1 is different from 01. For this reason the
default is to handle numeric attributes as tokens. If conversion to
integer is enabled, negative values are silently accepted.true
for XML and false for SGML and HTML dialects.false. Setting this option sets the
case_sensitive_attributes to the same value. This option
was added to support HTML quasi quotations and most likely has little
value in other contexts.false.false, only the attributes occurring in the
source are emitted.CDATA entities can be specified with this construct.
Multiple entity options are allowed.max_errors(-1) makes the parser continue, no matter how
many errors it encounters.
error(limit_exceeded(max_errors, Max), _)
max_memory(0)
(the default) means no resource limit will be enforced.
SGML2PL has four modes for handling white-space. The initial mode can
be switched using the space(SpaceMode) option to
load_structure/3
and set_sgml_parser/2.
In XML mode, the mode is further controlled by the xml:space
attribute, which may be specified both in the DTD and in the document.
The defined modes are:
sgml space-mode, all consequtive white-space
is reduced to a single space-character. This mode canonicalises all
white space.default, all leading and trailing
white-space is removed from CDATA objects. If, as a result,
the CDATA becomes empty, nothing is passed to the
application. This mode is especially handy for processing
`data-oriented' documents, such as RDF. It is not suitable for normal
text documents. Consider the HTML fragment below. When processed in this
mode, the spaces between the three modified words are lost. This mode is
not part of any standard; XML 1.0 allows only default and preserve.
Consider adjacent <b>bold</b> <ul>and</ul> <it>italic</it> words.
The parser can operate in two modes: sgml mode and xml
mode, as defined by the dialect(Dialect) option. Regardless
of this option, if the first line of the document reads as below, the
parser is switched automatically into XML mode.
<?xml ... ?>
Currently switching to XML mode implies:
<element [attribute...] /> is
recognised as an empty element.
lt (<), gt
(>), amp (&), apos
(') and quot (").
ELEMENT, etc.).
_) and colon (:) are
allowed in names.
preserve. In addition to setting
white-space handling at the toplevel the XML reserved attribute
xml:space is honoured. It may appear both in the document
and the DTD. The remove extension is honoured as
xml:space value. For example, the DTD statement below
ensures that the pre element preserves space, regardless of
the default processing mode.
<!ATTLIST pre xml:space nmtoken #fixed preserve>
Using the dialect xmlns, the parser will
interpret XML namespaces. In this case, the names of elements are
returned as a term of the format
URL:
If an identifier has no namespace and there is no default namespace it is returned as a simple atom. If an identifier has a namespace but this namespace is undeclared, the namespace name rather than the related URL is returned.
Attributes declaring namespaces (xmlns:<ns>=<url>)
are reported as if xmlns were not a defined resource.
In many cases, getting attribute-names as url:name is not desirable. Such terms are hard to unify and sometimes multiple URLs may be mapped to the same identifier. This may happen due to poor version management, poor standardisation or because the the application doesn't care too much about versions. This package defines two call-backs that can be set using set_sgml_parser/2 to deal with this problem.
The call-back xmlns is called as XML namespaces are
noticed. It can be used to extend a canonical mapping for later use by
the urlns call-back. The following illustrates this
behaviour. Any namespace containing rdf-syntax in its URL
or that is used as
rdf namespace is canonicalised to rdf. This
implies that any attribute and element name from the RDF namespace
appears as
rdf:\bnfmeta{name}
:- dynamic
xmlns/3.
on_xmlns(rdf, URL, _Parser) :- !,
asserta(xmlns(URL, rdf, _)).
on_xmlns(_, URL, _Parser) :-
sub_atom(URL, _, _, _, 'rdf-syntax'), !,
asserta(xmlns(URL, rdf, _)).
load_rdf_xml(File, Term) :-
load_structure(File, Term,
[ dialect(xmlns),
call(xmlns, on_xmlns),
call(urlns, xmlns)
]).
The library provides iri_xml_namespace/3 to break down an IRI into its namespace and localname:
# or /
?- iri_xml_namespace('http://example.com/images#12345', NS, L).
NS = 'http://example.com/images#12345',
L = ''.
As we see from the example above, the Localname can be the empty atom. Similarly, Namespace can be the empty atom if IRI is an XML name. Applications will often have to check for either or both these conditions. We decided against failing in these conditions because the application typically wants to know which of the two conditions (empty namespace or empty localname) holds. This predicate is often used for generating RDF/XML from an RDF graph.
The DTD (Document Type Definition) is a separate entity in sgml2pl, that can be created, freed, defined and inspected. Like the parser itself, it is filled by opening it as a Prolog output stream and sending data to it. This section summarises the predicates for handling the DTD.
dialect option from open_dtd/3
and the encoding option from open/4.
Notably the dialect option must match the dialect used for
subsequent parsing using this DTD.sgml. Using xml
or
xmlns processes the DTD case-sensitive.
dtd using
the call:
...,
absolute_file_name(dtd(Type),
[ extensions([dtd]),
access(read)
], DtdFile),
...
Note that DTD objects may be modified while processing errornous
documents. For example, loading an SGML document starting with
<?xml ...?> switches the DTD to XML mode and
encountering unknown elements adds these elements to the DTD object.
Re-using a DTD object to parse multiple documents should be restricted
to situations where the documents processed are known to be error-free.
The DTD html is handled seperately. The Prolog flag
html_dialect specifies the default html dialect, which is
either
html4 or html5 (default).3Note
that HTML5 has no DTD. The loaded DTD is an informal DTD that includes
most of the HTML5 extensions (http://www.cs.tut.fi/~jkorpela/html5-dtd.html).
In addition, the parser sets the dialect flag of the DTD
object. This is used by the parser to accept HTML extensions.
Next, the corresponding DTD is loaded.
omit(OmitOpen, OmitClose), where both
arguments are booleans (true or false
representing whether the open- or close-tag may be omitted. Content
is the content-model of the element represented as a Prolog term. This
term takes the following form:
cdata, but entity-references are expanded.*(SubModel)?(SubModel)+(SubModel),(SubModel1, SubModel2)|cdata, entity,
id, idref, name, nmtoken,
notation, number or nutoken. For
DTD types that allow for a list, the notation list(Type) is
used. Finally, the DTD construct (a|b|...) is mapped to the
term
nameof(ListOfValues).
Default describes the sgml default. It is one required,
current, conref or implied. If a
real default is present, it is one of default(Value) or fixed(Value).
NOTATION
declarations.system(+File) and/or
public(+PublicId).
As this parser allows for processing partial documents and process the DTD separately, the DOCTYPE declaration plays a special role.
If a document has no DOCTYPE declaraction, the parser returns a list holding all elements and CDATA found. If the document has a DOCTYPE declaraction, the parser will open the element defined in the DOCTYPE as soon as the first real data is encountered.
Some documents have no DTD. One of the neat facilities of this
library is that it builds a DTD while parsing a document with an
implicit DTD. The resulting DTD contains all elements
encountered in the document. For each element the content model is a
disjunction of elements and possibly #PCDATA that can be
repeated. Thus, if we found element y and CDATA in element
x, the model is:
<!ELEMENT x - - (y|#PCDATA)*>
Any encountered attribute is added to the attribute list with the
type
CDATA and default #IMPLIED.
The example below extracts the elements used in an unknown XML document.
elements_in_xml_document(File, Elements) :-
load_structure(File, _,
[ dialect(xml),
dtd(DTD)
]),
dtd_property(DTD, elements(Elements)),
free_dtd(DTD).
dtd(DTD) option.file(File)
option.
stream_property(Stream, position(Position)).
sgml, but implies shorttag(false)
and accepts XML empty element declarations (e.g.,
<img src="..."/>).html, accept attributes named data-
without warning. This value initialises the charset to UTF-8.xml. Dialect
xhtml5 accepts attributes named data- without
warning.<?xml ...> is encountered. See section
3.3 for details.qualify_attributes
option below.
xmlns) mode. Default and standard
compliant is not to qualify such elements. If true, such
attributes are qualified with the namespace of the element they appear
in. This option is for backward compatibility as this is the behaviour
of older versions. In addition, the namespace document suggests
unqualified attributes are often interpreted in the namespace of their
element.token (default), attributes of type number are passed as
a Prolog atom. If integer, such attributes are translated
into Prolog integers. If the conversion fails (e.g. due to overflow) a
warning is issued and the value is passed as an atom.encoding= attribute in the header.
Explicit use of this option is only required to parse non-conforming
documents. Currently accepted values are iso-8859-1 and
utf-8.<!DOCTYPE
declaration has been parsed, the default is the defined doctype. The
parser can be instructed to accept the first element encountered as the
toplevel using doctype(_). This feature is especially
useful when parsing part of a document (see the parse
option to
sgml_parse/2.
on_begin, etc.
callbacks from sgml_parse/2.sgml,
html, html5, xhtml, xhtml5, xml
or xmlns).begin or end) is caused by
an element written down using the shorttag notation (<tag/value/>.#pcdata is part of
Elements. If no element is open, the doctype is
returned.
This option is intended to support syntax-sensitive editors. Such an editor should load the DTD, find an appropriate starting point and then feed all data between the starting point and the caret into the parser. Next it can use this option to determine the elements allowed at this point. Below is a code fragment illustrating this use given a parser with loaded DTD, an input stream and a start-location.
...,
seek(In, Start, bof, _),
set_sgml_parser(Parser, charpos(Start)),
set_sgml_parser(Parser, doctype(_)),
Len is Caret - Start,
sgml_parse(Parser,
[ source(In),
content_length(Len),
parse(input) % do not complete document
]),
get_sgml_parser(Parser, allowed(Allowed)),
...
Input is a stream. A full description of the option-list is below.
source(Stream), this implies reading is stopped as soon as
the element is complete, and another call may be issued on the same
stream to read the next element.content is like element but assumes
the element has already been opened. It may be used in a call-back from
call(on_begin, Pred) to parse individual
elements after validating their headers.doctype
declaration.allowed(Elements) option of get_sgml_parser/2.
It disables the parser's default to complete the parse-tree by closing
all open elements.
informational.
quiet, the error is suppressed. Can be used
together with call(urlns, Closure) to provide external
expansion of namespaces. See also section
3.3.1.Handler(+Tag, +Attributes, +Parser).
Handler(+Tag, +Parser).Handler(+CDATA, +Parser), where CDATA is an atom
representing the data.Handler(+Text, +Parser),
where
Text is the text of the processing instruction.<!...>) has been read. The named
handler is called with two arguments: Handler(+Text,
+Parser), where Text is the text of the declaration
with comments removed.
This option is expecially useful for highlighting declarations and comments in editor support, where the location of the declaration is extracted using get_sgml_parser/2.
Handler(+Severity, +Message, +Parser),
where
Severity is one of warning or error
and
Message is an atom representing the diagnostic message. The
location of the error can be determined using get_sgml_parser/2
If this option is present, errors and warnings are not reported using print_message/3
xmlns mode, a new namespace declaraction
is pushed on the environment. The named handler is called with three
arguments: Handler(+NameSpace, +URL, +Parser).
See section 3.3.1 for details.xmlns mode, this predicate can be used
to map a url into either a canonical URL for this namespace or another
internal identifier. See section 3.3.1
for details.
In some cases, part of a document needs to be parsed. One option is
to use load_structure/2
or one of its variations and extract the desired elements from the
returned structure. This is a clean solution, especially on small and
medium-sized documents. It however is unsuitable for parsing really big
documents. Such documents can only be handled with the call-back output
interface realised by the
call(Event, Action) option of sgml_parse/2.
Event-driven processing is not very natural in Prolog.
The SGML2PL library allows for a mixed approach. Consider the case
where we want to process all descriptions from RDF elements in a
document. The code below calls process_rdf_description(Element)
on each element that is directly inside an RDF element.
:- dynamic
in_rdf/0.
load_rdf(File) :-
retractall(in_rdf),
open(File, read, In),
new_sgml_parser(Parser, []),
set_sgml_parser(Parser, file(File)),
set_sgml_parser(Parser, dialect(xml)),
sgml_parse(Parser,
[ source(In),
call(begin, on_begin),
call(end, on_end)
]),
close(In).
on_end('RDF', _) :-
retractall(in_rdf).
on_begin('RDF', _, _) :-
assert(in_rdf).
on_begin(Tag, Attr, Parser) :-
in_rdf, !,
sgml_parse(Parser,
[ document(Content),
parse(content)
]),
process_rdf_description(element(Tag, Attr, Content)).
The parser can deal with ISO Latin-1 and UTF-8 encoded files, doing
decoding based on the encoding argument provided to
set_sgml_parser/2
or, for XML, based on the encoding attribute of the XML
header. The parser reads from SWI-Prolog streams, which also provide
encoding handling. Therefore, there are two modes for parsing. If the
SWI-Prolog stream has encoding octet (which is the default
for binary streams), the decoder of the SGML parser will be used and
positions reported by the parser are octet offsets in the stream. In
other cases, the Prolog stream decoder is used and offsets are character
code counts.
The library xpath.pl provides predicates to select nodes
from an XML DOM tree as produced by library(sgml) based on
descriptions inspired by the XPATH language.
The predicate xpath/3 selects a sub-structure of the DOM non-deterministically based on an xpath-like specification. Not all selectors of XPATH are implemented, but the ability to mix xpath/3 calls with arbitrary Prolog code provides a powerful tool for extracting information from XML parse-trees.
///The Terms above are of type callable. The functor specifies
the element name. The element name '*' refers to any element. The name self
refers to the top-element itself and is often used for processing
matches of an earlier xpath/3 query.
A term NS:Term refers to an XML name in the namespace NS. Optional
arguments specify additional constraints and functions. The arguments
are processed from left to right. Defined conditional argument values
are:
lastlast - IntExprDefined function argument values are:
selfcontenttextnormalize_spacetext, but uses normalize_space/2
to normalise white-space in the output
number@AttributeIn addition, the argument-list can be conditions:
content = content defines
that the content of the element is the atom content. The
functions lower_case and upper_case can be
applied to Right (see example below).
contains(Haystack, Needle)h3 element
inside a div element, where the div element
itself contains an h2 child with a strong
child.
//div(h2/strong)/h3
This is equivalent to the conjunction of Xpath goals below.
..., xpath(DOM, //div, Div), xpath(Div, h2/strong, _), xpath(Div, h3, Result)
Examples:
Match each table-row in DOM:
xpath(DOM, //tr, TR)
Match the last cell of each tablerow in DOM. This example illustrates that a result can be the input of subsequent xpath/3 queries. Using multiple queries on the intermediate TR term guarantee that all results come from the same table-row:
xpath(DOM, //tr, TR), xpath(TR, /td(last), TD)
Match each href attribute in an <a>
element
xpath(DOM, //a(@href), HREF)
Suppose we have a table containing rows where each first column is the name of a product with a link to details and the second is the price (a number). The following predicate matches the name, URL and price:
product(DOM, Name, URL, Price) :-
xpath(DOM, //tr, TR),
xpath(TR, td(1), C1),
xpath(C1, /self(normalize_space), Name),
xpath(C1, a(@href), URL),
xpath(TR, td(2, number), Price).
Suppose we want to select books with genre="thriller" from a tree
containing elements <book genre=...>
thriller(DOM, Book) :-
xpath(DOM, //book(@genre=thiller), Book).
Math the elements `<table align="center"> _and_<table align="CENTER">`:
//table(@align=lower_case(center))
In some cases applications wish to process small portions of large SGML, XML or RDF files. For example, the OpenDirectory project by Netscape has produced a 90MB RDF file representing the main index. The parser described here can process this document as a unit, but loading takes 85 seconds on a Pentium-II 450 and the resulting term requires about 70MB global stack. One option is to process the entire document and output it as a Prolog fact-base of RDF triplets, but in many cases this is undesirable. Another example is a large SGML file containing online documentation. The application normally wishes to provide only small portions at a time to the user. Loading the entire document into memory is then undesirable.
Using the parse(element) option, we open a file, seek
(using seek/4)
to the position of the element and read the desired element.
The index can be built using the call-back interface of
sgml_parse/2.
For example, the following code makes an index of the structure.rdf
file of the OpenDirectory project:
:- dynamic
location/3. % Id, File, Offset
rdf_index(File) :-
retractall(location(_,_)),
open(File, read, In, [type(binary)]),
new_sgml_parser(Parser, []),
set_sgml_parser(Parser, file(File)),
set_sgml_parser(Parser, dialect(xml)),
sgml_parse(Parser,
[ source(In),
call(begin, index_on_begin)
]),
close(In).
index_on_begin(_Element, Attributes, Parser) :-
memberchk('r:id'=Id, Attributes),
get_sgml_parser(Parser, charpos(Offset)),
get_sgml_parser(Parser, file(File)),
assert(location(Id, File, Offset)).
The following code extracts the RDF element with required id:
rdf_element(Id, Term) :-
location(Id, File, Offset),
load_structure(File, Term,
[ dialect(xml),
offset(Offset),
parse(element)
]).
While processing an SGML document the document may refer to external
data. This occurs in three places: external parameter entities, normal
external entities and the DOCTYPE declaration. The current
version of this tool deals rather primitively with external data.
External entities can only be loaded from a file and the mapping between
the entity names and the file is done using a catalog file in a
format compatible with that used by James Clark's SP Parser, based on
the SGML Open (now OASIS) specification.
Catalog files can be specified using two primitives: the predicate
sgml_register_catalog_file/2
or the environment variable
SGML_CATALOG_FILES (compatible with the SP package).
start or end and defines whether the
catalog is considered first or last. This predicate has no effect if File
is already part of the catalog.
If no files are registered using this predicate, the first query on
the catalog examines SGML_CATALOG_FILES and fills the
catalog with all files in this path.
Two types of lines are used by this package.
DOCTYPEdoctype file
PUBLIC"Id"file
The specified file path is taken relative to the location
of the catolog file. For the DOCTYPE declaraction, library(sgml)
first makes an attempt to resolve the SYSTEM or PUBLIC
identifier. If this fails it tries to resolve the doctype
using the provided catalog files.
Strictly speaking, library(sgml) breaks the rules for
XML, where system identifiers must be Universal Resource Indicators, not
local file names. Simple uses of relative URIs will work correctly under
UNIX and Windows.
In the future we will design a call-back mechanism for locating and processing external entities, so Prolog-based file-location and Prolog resources can be used to store external entities.
PWP is an approach to server-side scripting using Prolog which is based on a simple key principle:
Especially when generating XML rather than HTML, this is such an obvious thing to do. We have many kinds of XML checking tools.
Having decided that the input should be well formed, that means NO NEW SYNTAX
None of the weird and horrible <% ... %> or whatever not-quite-XML stuff you see in other template systems, making checking so very hard (and therefore, making errors so distressingly common).
That in turns means that PWP "markup" must be based on special elements or special attributes. The fact that an XML parser must allow undeclared attributes on any element even when validating, but must not allow undeclared elements, suggests doing this through attributes. In particular, one should be able to take an existing DTD, such as an XHTML DTD, and just use that without modification. So the design reduces to
This description uses the following name space:
xmlns:pwp='http://www.cs.otago.ac.nz/staffpriv/ok/pwp.pl'
The attributes are
| xml
| 'one non-alphanumeric character'
Here's what they mean. Each element is expanded in the context of a set of variable bindings. After expansion, if the tag is not mapped to '-', all attributes in the pwp: namespace are removed and the children elements are recursively expanded.
| xml | text-file |
xml-file | pwp-file
Term is a Prolog term; variables in Term are bound by the context. An empty Term is regarded as a missing value for this attribute. The Prolog variable CONTEXT refers to the entire context, a list of Name = Value, where Name is a Prolog atom holding the name of the context variable and Value is an arbitrary Prolog term.
write(Datum)
writeq(Datum)
write_canonical(Datum)
print(Datum)
print(Datum)
format(Format)
format(Format, Arguments)
The value of Term must be an XML term as defined in the SGML2PL documentation or a list of such terms. A single term is taken as if it had been [Term]. The resulting list of terms replaces the children of the current element and will not be further processed.
The value of Term is used to define a sequence of characters. That sequence of characters is used as a file name. The file is read as a sequence of characters, and that sequence used as character data.
The value of Term is used to define a sequence of characters. That sequence of characters is used as a file name. The file is loaded as XML, and the sequence of XML items thus obtained used. This means that PWP provides XML inclusion without depending on the parser to support XInclude.
Like xml-file, but PWP attributes are evaluated and processed. The current context variables are passed to the PWP processor.
The default value for pwp:how is text.
If pwp:tag is missing or the value is empty, the current element appears in the output (after further processing) with its present tag. If pwp:tag is a QName, the current element appears (...) with that as its tag. That option is most useful in DTDs, where an "authoring" DTD may use one tag and have it automatically mapped to another tag in the output, e.g., <item> -> <li>. Finally, if pwp:tag is '-', the children of the current element (either the result of pwp:use or the transformed original children, whichever applies) appear in the output but there is no element around them. A missing or empty pwp:ask is just like pwp:ask = 'true'.
| 'one non-alphanumeric character'.
Attributes in the pwp namespace are not affected by this attribute. Such attributes are always stripped out and never substituted into. If pwp:att is missing or empty, attributes of the current element are copied over to the output unchanged. If pwp:att = 'c' for some non-alphanumeric character c, each attribute is examined for occurrences of c(...)c and c[...]c which are as short as possible. There is no one character which could be used every time, so you have to explicitly choose a substitution marker which is safe for the data you do not want to be altered. None of the pwp attributes are inherited, least of all this one. Text outside c(...)c groups is copied unchanged; text inside a c(...)c group is parsed as a Prolog term and treated as if by pwp:how = text. Text inside a c[...]c group is evaluated (in the current context), and if it fails, the entire attribute will be removed from the element.
Examples:
<html
xmlns:pwp="http://www.cs.otago.ac.nz/staffpriv/ok/pwp.pl"
pwp:ask = "ensure_loaded(msg), once(msg(Greeting))">
<head>
<title pwp:use="Greeting"/>
</head>
<body>
<p><span pwp:use="Greeting" pwp:tag='-'/></p>
</body>
</html>
where msg.pl contains
msg('Hello, World!').
This example illustrates an important point. Prolog Well-Formed Pages provide NO way to physically incorporate Prolog clauses into a page template. Prolog clauses must be put in separate files which can be checked by a Prolog syntax checker, compiler, cross-referencer, &c WITHOUT the Prolog tool in question needing to know anything whatsoever about PWP. You load the files using pwp:ask on the root element.
<html
xmlns:pwp="http://www.cs.otago.ac.nz/staffpriv/ok/pwp.pl">
<head><title>Example 2</title></head>
<body pwp:ask="Hello = 'Hello world', A = 20, B = 22">
<h1 pwp:use="Hello"/>
<p>The answer is <span pwp:use="C" pwp:ask="C is A+B"/>.</p>
</body>
</html>
staff.pl
defining
staff(NickName, FullName, Office, Phone, E_Mail_Address).
status(NickName, full_time | part_time). We want to make a
phone list of full time staff.
<html
xmlns:pwp="http://www.cs.otago.ac.nz/staffpriv/ok/pwp.pl"
pwp:ask='ensure_loaded(staff)'>
<head>
<title>Phone list for Full-Time staff.</title>
</head>
<body>
<h1>Phone list for Full-Time staff.</h1>
<table
pwp:ask = "setof(FullName-Phone,
N^O^E^(
status(N, full_time),
staff(N, FullName, O, Phone, E)
),
Staff_List)">
<tr><th>Name</th><th>Phone</th></tr>
<tr pwp:ask="member(FullName-Phone, Staff_List)">
<td pwp:use="FullName"/>
<td pwp:use="Phone"/>
</tr>
</table>
</body>
</html>
<html
xmlns:pwp="http://www.cs.otago.ac.nz/staffpriv/ok/pwp.pl"
pwp:ask='ensure_loaded(staff)'>
<head>
<title>Phone list for Full-Time staff.</title>
</head>
<body>
<h1>Phone list for Full-Time staff.</h1>
<table
pwp:ask = "setof(FullName-E_Mail,
N^O^P^staff(N, FullName, O, P, E_Mail),
Staff_List)">
<tr><th>Name</th><th>Address</th></tr>
<tr pwp:ask="member(FullName-E_Mail, Staff_List)">
<td pwp:use="FullName"/>
<td><a pwp:use="E_Mail"
pwp:att='$' href="mailto:$(E_Mail)$"/></td>
</tr>
</table>
</body>
</html>
<html
xmlns:pwp="http://www.cs.otago.ac.nz/staffpriv/ok/pwp.pl">
<head><title>$SHELL</title></head>
<body>
<p pwp:ask="getenv('SHELL', Shell)"
>The default shell is <span pwp:tag="-" pwp:use="Shell"/>.</p>
<p pwp:ask="\+getenv('SHELL',_)">There is no default shell.</p>
</body>
</html>
There is one other criterion for a good server-side template language:
It should be possible to compile templates so as to eliminate most if not all interpretation overhead.
This particular notation satisfies that criterion with the limitation that the conversion of a term to character data requires run-time traversal of terms (because the terms are not known until run time).
The library library(sgml_write) provides the inverse of
the parser, converting the parser's output back into a file. This
process is fairly simple for XML, but due to the power of the SGML DTD
it is much harder to achieve a reasonable generic result for SGML.
These predicates can write the output in two encoding schemas depending on the encoding of the Stream. In UTF-8 mode, all characters are encoded using UTF-8 sequences. In ISO Latin-1 mode, characters outside the ISO Latin-1 range are represented using a named character entity if provided by the DTD or a numeric character entity.
false, the XML header is suppressed.
Useful for embedding in other XML streams.
false,
no layout characters are added. As this mode does not need to analyse
the document it is faster and guarantees correct output when read back.
Unfortunately the output is hardly human readable and causes problems
with many editors.
header
and
ident is added to use xml_write/3
to generate XML that is embedded in a larger XML document.
<foo/> (default,
net(true)) or <foo></foo> (net(false)).
For SGML, this applies to empty elements, so you get <foo>
(if foo is declared to be EMPTY in the DTD),
<foo></foo> (default, net(false))
or
<foo// (net(true)). In SGML code, short
character content not containing /<b>xxx</b> (default, net(false)
or <b/xxx/ (net(true))
DOCTYPE header and the content of the
document as represented by Term to Stream. The Options
are described with xml_write/3.In most cases, the preferred way to create an XML document is to
create a Prolog tree of element(Name, Attributes, Content)
terms and call xml_write/3
to write this to a stream. There are some exceptions where one might not
want to pay the price of the intermediate representation. For these
cases, this library contains building blocks for emitting markup data.
The quote funtions return a version of the input text into one that
contains entities for characters that need to be escaped. These are the
XML meta characters and the characters that cannot be expressed by the
document encoding. Therefore these predicates accept an encoding
argument. Accepted values are ascii,
iso_latin_1, utf8 and unicode.
Versions with two arguments are provided for backward compatibility,
making the safe
ascii encoding assumption.
<>&".4Older
versions also mapped ' to '.
Characters that cannot represented in Encoding are mapped to
XML character entities.ascii encoding.ascii encoding.ascii encoding.
The current parser is rather limited. While it is able to deal with many serious documents, it omits several less-used features of SGML and XML. Known missing SGML features include
<!ATTLIST #NOTATION name attributes>. Those data
attributes are provided when you declare an external CDATA, NDATA, or
SDATA entity.
XML does not include external CDATA, NDATA, or SDATA entities, nor any of the other uses to which data attributes are put in SGML, so it doesn't include data attributes for notations either.
Sgml2pl does not support this feature and is unlikely to; you should be aware that SGML documents using this feature cannot be converted faithfully to XML.
<tag/content/ is a valid abbreviation for
<tag>content</tag>, which can also be written
as
<tag>content</>. Empty start tags (<>),
unclosed start tags (<a<b</verb>) and unclosed
end tags (<verb></a<b) are not supported.
In XML mode the parser recognises SGML constructs that are not allowed in XML. Also various extensions of XML over SGML are not yet realised. In particular, XInclude is not implemented because the designers of XInclude can't make up their minds whether to base it on elements or attributes yet, let alone details.
The Prolog representation for parsed documents is based on the SWI-Prolog interface to SP by Anjo Anjewierden.
Richard O'Keefe has put a lot of effort testing and providing bug reports consisting of an illustrative example and explanation of the standard. He also made many suggestions for improving this document.